Jump to content


- - - - -

DataGrid (phần I)


2 replies to this topic

#1 mackeno

    Thượng Sĩ

  • Thành Viên Chính Thức
  • PipPipPip
  • 215 Bài viết:

Gửi lên vào 22 April 2003 - 09:30 AM

DataGrid (phần I)
Dùng Dataview để Filter và Sort
Thường thường, khi điều khiển trong thời gian thật (real-time control), là Operator, ta muốn các alarms có ưu tiên cao và mới xãy ra nhất được hiển thị trên hết. Đôi khi, ta chỉ muốn thấy các alarm priority 3 (ưu tiên cao nhất) mà thôi. Để thực hiện các việc nầy, ta dùng Dataview Object.

Thay vì dùng thẳng table alarm của DataSet alarmlist làm datasource của DataGrid1, ta sẽ dùng một DataView derived from (đến từ) table alarm. Ta có thể Sort (sắp theo thứ tự) các alarms/records theo Priority hay áp dụng Filter (sàn lọc) vào DataView để chỉ thấy những thứ gì mình muốn, thí dụ chỉ có alarms priority 3 thôi.

Nên nhớ là nằm đàng sau vẫn là table alarm, nhưng Dataview đóng vai trò cặp kiếng mát màu giúp cho ta thấy những thứ gì và theo cách ta muốn. Mỗi khi ta thay một cặp kiếng, ta lại thấy những thứ khác.

Dưới đây là Sub BtnLoadXMLData_Click được sửa lại một chút để dùng DataView:

Private Sub BtnLoadXMLData_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) _
Handles BtnLoadXMLData.Click
' Instantiate a DataSet type alarmlist
DS = New alarmlist()
' Load the XML data from file AlarmList.xml in the source code folder. Note that the program EXE resides
' in the bin subfolder
DS.ReadXml("../AlarmList.xml")
' Bind the Datagrid DataSource to this new DataSet table alarm
' DataGrid1.DataSource = DS.alarm
' Create a Dataview from DS
DV1 = New System.Data.DataView(DS.alarm)
' Sort alarms by priority, then datetime
' DESC stands for descending order,i.e. biggest on top
DV1.Sort = "priority DESC, datetime DESC"
' Bind the Datagrid DataSource to Dataview
DataGrid1.DataSource = DV1
AddCustomDataTableStyle()
' Display the number of alarms in each priority
DisplayTotal()
End Sub



Để ý Dataview object DV1 được derived từ DS.alarm. Sau đó ta Sort các alarms theo thứ tự ưu tiên, rồi trong số những alarm có cùng priority ta lại Sort chúng theo datetime (ở đây data type của datetime chỉ là string).

Ngoài ra để đếm con số các alarms thuộc mỗi priority ta có thể dùng Dataview với filter rồi xem property Count của nó như sau:
Private Sub DisplayTotal()
' Create a Dataview object from table DS.alarm
Dim DVP1 As New System.Data.DataView(DS.alarm)
' Apply filter
DVP1.RowFilter = "priority = 1"
' Display Count of records in this Dataview
NumPrio1.Text = "Prio1: " & DVP1.Count.ToString
Dim DVP2 As New System.Data.DataView(DS.alarm)
DVP2.RowFilter = "priority = 2"
NumPrio2.Text = "Prio2: " & DVP2.Count.ToString
Dim DVP3 As New System.Data.DataView(DS.alarm)
DVP3.RowFilter = "priority = 3"
NumPrio3.Text = "Prio3: " & DVP3.Count.ToString
NumTotal.Text = "Total: " & DS.alarm.Rows.Count.ToString
Dim bmb As BindingManagerBase = Me.BindingContext(DataGrid1.DataSource, DataGrid1.DataMember)
NumDisplayed.Text = "Displayed: " & bmb.Count.ToString
End Sub



Chắc bạn đã để ý thấy thay vì iterate qua mỗi record để đếm con số alarms thuộc priority 1,2 hay 3, ta đã dùng ba Dataviews để filter ra alarms thuộc ba priorities khác nhau rồi lấy trị số Count của mỗi Dataview. Đây là lối lập trình dựa vào những gì có sẵn càng nhiều càng tốt để tránh tạo ra bugs.

Ngoài ra, để đếm con số hàng alarms được thật sự hiển thị bất cứ lúc nào ta dùng BindingManagerBase object trong hai hàng code dưới đây:

Dim bmb As BindingManagerBase = Me.BindingContext(DataGrid1.DataSource, DataGrid1.DataMember)
NumDisplayed.Text = "Displayed: " & bmb.Count.ToString



Ta đặt thêm ba buttons để filter alarms với code sau đây:
Private Sub Btn1and2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) _
Handles Btn1and2.Click
DV1.RowFilter = "priority < 3"
Dim bmb As BindingManagerBase = Me.BindingContext(DataGrid1.DataSource, DataGrid1.DataMember)
NumDisplayed.Text = "Displayed: " & bmb.Count.ToString
End Sub

Private Sub Btn1Only_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) _
Handles Btn1Only.Click
DV1.RowFilter = "priority = 1"
Dim bmb As BindingManagerBase = Me.BindingContext(DataGrid1.DataSource, DataGrid1.DataMember)
NumDisplayed.Text = "Displayed: " & bmb.Count.ToString
End Sub

Private Sub BtnAllAlarms_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) _
Handles BtnAllAlarms.Click
DV1.RowFilter = ""
Dim bmb As BindingManagerBase = Me.BindingContext(DataGrid1.DataSource, DataGrid1.DataMember)
NumDisplayed.Text = "Displayed: " & bmb.Count.ToString
End Sub



Bạn có thể chay chương trình và bấm các nút vừa mới thêm vào để xem các alarms được filtered như thế nào.

Làm việc với một Row trong DataGrid
Khi một alarm mới được báo cáo và hiển thị, hệ thống điều khiển real-time thường hay phát ra những tiếng Beep nho nhỏ để nhắc Operator xử lý sự cố tạo ra alarm. Việc đầu tiên Operator sẽ làm là Acknowledge (xác nhận là tôi biết rồi, khổ lắm, nói mãi!) cái alarm bằng cách right click lên Row hiển thị alarm rồi click menuCommand Acknowledge từ PopupMenu.

Khi bạn đã Acknowledge một alarm rồi thì cái ACKN checkbox sẽ được đánh dấu và nếu hệ thống không còn alarm nào chưa được acknowledged thì nó sẽ ngừng Beep. Ngoài ra, có khi vì bạn biết là lý do gây ra một alarm nào đó không quan trọng (thí dụ nhân viên kỹ thuật đang sửa và thử cái sensor của alarm ấy) và bạn không muốn alarm ấy được báo cáo trong tương lai, bạn có thể Isolate (cô lập hóa) nó. Khi nào muốn cho nó hoạt động bình thường trở lại, bạn sẽ Enable (tác động) nó.

Bây giờ bạn hãy đặt một ContextMenu control vào form và Edit cho nó ba menuCommands tên mnuAckn(Acknowledge), mnuIsolate(Isolate) và mnuEnable(Enable) như trong hình dưới đây:

Mỗi khi user right click lên một hàng alarm, ContextMenu1 sẽ hiển thị chỉ những menuCommands thích hợp với tình huống. Tức là nếu alarm chưa được acknowledged thì mới có menuCommand Acknowledge, khi alarm chưa bị isolated thì mới có menuCommand Isolate, nếu đã bị isolated rồi thì chỉ có MenuCommand Enable.

Bình thường, nếu bạn click lên một checkbox còn trống trong DataGrid1, checkbox ấy sẽ được đánh dấu. Nhưng trong chương trình của chúng ta tại đây ta không muốn cho user làm việc ấy mà phải Acknowlege, Isolate hay Enable bằng PopupMenu. Do đó bạn hãy cho property ReadOnly của DataGrid1 bằng True.

Lúc chương trình nhận được Event MouseDown từ DataGrid1 ta sẽ tìm cách xác định lúc bấy giờ Mouse đang nằm trên alarm line nào bằng cách chạy Method HitTest của DataGrid1. Khi DataGrid1 HitTest vị trí của Mouse với instruction myGrid.HitTest(e.X, e.Y), nó sẽ cho ta một Object HitTestInfo. Property Row của HitTestInfo là hàng thứ mấy trong DataGrid1.

Để lấy ra đúng DataRowView nào đang hiển thị ở HitTestInfo.Row ấy ta phải dựa vào BindingManagerBase. Cái DataRowView mà ta đang tìm chính là DataRowView của BindingManagerBase với position bằng HitTestInfo.Row ấy.

Trong chương trình nầy, ta sẽ chứa DataRowView ấy trong variable drv. Dưới đây là code để xử lý Event MouseDown của DataGrid1, để ý là ta hiển thị bên dưới cái description của alarm được clicked bằng statement Label1.Text = drv("description") để cho user một feedback:

' Variable used to store selected DataRowView
Dim drv As DataRowView
Private Sub DataGrid1_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) _
Handles DataGrid1.MouseDown
' Only proceed when Mouse Right Button was clicked
If e.Button <> MouseButtons.Right Then Exit Sub
' Typecast sender to DataGrid data type. myGrid is actually DataGrid1
Dim myGrid As DataGrid = CType(sender, DataGrid)
' Declare a HitTestInfo variable
Dim hti As DataGrid.HitTestInfo
' Obtain the info about Mouse location
hti = myGrid.HitTest(e.X, e.Y)
' Only proceed when a Cell was hit
If hti.Type = DataGrid.HitTestType.Cell Then
Try
' Obtain BindingManagerBase of DataGrid1
Dim bmb As BindingManagerBase = Me.BindingContext(myGrid.DataSource, myGrid.DataMember)
' Position at DataRowView corresponding to the physical row that was hit
bmb.Position = hti.Row
' Store the found DataRowView in temporary variable drv
drv = bmb.Current
' Display description of the alarm line as a feedback
Label1.Text = drv("description")
If Not (drv Is Nothing) Then
' Only display the MenuCommands that are appropriate to this context
Dim ctx As DataRow = drv.Row
If Not (ctx Is Nothing) Then
If drv("ackn") = True Then
mnuAckn.Visible = False
Else
' Only display menuCommand Ackn when alarm is not yet acknowledged
mnuAckn.Visible = True
End If
If drv("isolate") = True Then
' If alarm is already isolated then only display MenuCommand Enable
mnuIsolate.Visible = False
mnuEnable.Visible = True
Else
mnuIsolate.Visible = True
mnuEnable.Visible = False
End If
' Popup context menu
ContextMenu1.Show(myGrid, New Point(e.X, e.Y))
End If
End If
Catch ex As Exception
MessageBox.Show(ex.ToString())
End Try
End If
End Sub



Khi User click một trong các Popup menu commands ta thay đổi các boolean value Ackn hay Isolate và viết xuống AlarmList.xml data file như sau:

Private Sub mnuAckn_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuAckn.Click
If Not drv Is Nothing Then
drv("ackn") = True
UpdatePoint()
End If
End Sub
Private Sub mnuIsolate_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuIsolate.Click
If Not drv Is Nothing Then
drv("isolate") = True
UpdatePoint()
End If
End Sub
Private Sub mnuEnable_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuEnable.Click
If Not drv Is Nothing Then
drv("isolate") = False
UpdatePoint()
End If
End Sub
Private Sub UpdatePoint()
' Accept the changes in DataSet
DS.AcceptChanges()
' Write updated data to XML file to persist the information
DS.WriteXml("..\AlarmList.xml")
End Sub



Khi khởi động chương trình và right click lên alarm point 402-2-9 để Acknowledge nó bạn sẽ thấy như sau:



Bạn có thể tải về chương trình AlarmList nầy tại đây.
Edit một XML Schema
Trong chương trình mới nầy ta sẽ có một áp dụng khác cho DataGrid. Ta muốn tạo ra một DataForm để Edit chi tiết của các Operators, những người được phép dùng hệ thống điều khiển Real-time On-line để Acknowledge alarm, mở, tắt các quạt, máy bơm,.v.v..

DataForm nầy sẽ có một DataGrid nằm bên dưới cho ta một hình spreadsheet của tất cả các Operator records, và ta có thể chọn làm việc với record nào bằng cách click bên trái của record ấy trong spreadsheet.

Trước hết bạn hãy khởi động một project mới tên Operators. Kế đó dùng IDE MenuCommand Project | Add New Item để thêm một XML Schema bằng cách click lên icon XML Schema. Chỗ Name XMLSchema1.xsd hãy sửa nó thành operatorlist.xsd như trong hình dưới đây:


Để Edit cái schema mới nầy, bạn hãy doubleclick lên tên operatorlist.xsd trong Solution Explorer. Một khung vàng nhạt còn trống sẽ hiện ra ở giữa. Bạn hãy drag icon E Element từ XML Schema Toolbox (nằm bên trái ) vào khung vàng nhạt. Hãy click lên chữ Element1 (nằm bên phải chữ E) trong hình mới tạo ra và sửa nó thành operator như trong hình dưới đây:

Kế đó drag icon A Attribute từ XML Schema Toolbox vào drop nó ngay trên hàng nằm dưới Element operator. Sửa tên Attribute đó thành operatorid. Click bên phải chữ string của operatorid để chọn datatype integer từ ComboBox. Lập lại cùng những thao tác ấy cho Attributes username, password và level. Click bên phải chữ string của level để chọn datatype integer từ ComboBox.

Hể trị số level của một operator càng lớn thì operator ấy càng có quyền để làm nhiều chuyện. MasterUser là người có level cao nhất. Mỗi command trong hệ thống điều khiển Real-time được cho một level mà user phải có một level với trị số ít nhất là bằng nó thì mới dùng command ấy được. Thí dụ Command Modify Username/Password/Level có level bằng 5 thì chỉ có MasterUser với level bằng 5 mới dùng nó được.

Đến đây ta đã định nghĩa xong các Attributes của một Element operator mà ta sẽ dùng làm record trong Table operator trong cơ sỡ dữ liệu XML. Để có một XML hợp lệ ta cần phải gói các Element operator vào trong một Element gốc (root) mà ta sẽ gọi nó là operatorlist.

Bạn hãy drag icon E Element từ XML Schema Toolbox vào khung vàng nhạt và sửa tên của Element đó thành operatorlist. Kế đó nắm góc trái trên (top left) của hình Element oparator và drag drop nó vào ngay hàng dưới chữ operatorlist của Element operatorlist. Bạn sẽ thấy hình dưới đây:

Nếu bây giờ bạn click Tab XML phía dưới của khung vàng nhạt bạn sẽ thấy mã nguồn XML của Schema operatorlist.xsd như sau:



Mã nguồn XML của Schema operatorlist.xsd cho thấy Element operatorlist là Element gốc (root) còn gọi là DocumentElement của XML nầy. Bên trong Element operatorlist có Element operator. Mỗi Element operator có những Attributes là operatorid, username, password và level. Để ý datatype của Attributes operatorid và level là integer.

Trở lại hình của Schema bằng cách click Tab Schema phía dưới, ta thấy hàng đầu tiên của mỗi khung chữ nhật chứa tên của Element chủ của khung ấy. Từ hàng thứ nhì trở xuống là định nghĩa những gì thuộc về Element ấy.

  • +
  • -
  • 0
Tiên trách kỷ, Hậu trách nhân

user posted image

#2 chiop01

    Trung Sĩ

  • Thành Viên Ưu Tú
  • PipPipPip
  • 155 Bài viết:

Gửi lên vào 03 May 2003 - 07:51 PM

Không đoc hết nên ko hỉu he he he....
  • +
  • -
  • 0

user posted imageuser posted imageuser posted imageuser posted imageuser posted imageuser posted imageuser posted image
You don't love a woman !
Because she is beautiful !
But she is beautiful !
Because you love her !

http://www.qod.us/

#3 mackeno

    Thượng Sĩ

  • Thành Viên Chính Thức
  • PipPipPip
  • 215 Bài viết:

Gửi lên vào 08 May 2003 - 02:30 PM

Bạn đọc nhiều lần là tự nhiên bạn hiểu ngay à !
thôi thì bạn đọc lần nửa xem, tôi nghĩ bạn hiểu đó !!
  • +
  • -
  • 0
Tiên trách kỷ, Hậu trách nhân

user posted image





1 người đang xem chủ đề này

0 thành viên, 1 khách, 0 ẩn danh